Dear Qing,
- Regarding how to modify the joint angles in the cervical spine, you should change the code for the cervical spine rhythm.
You can find the following pieces of the code in the ‘AMMR\Body\AAUHuman\TrunkNeck\JointsTrunkLumbarNeck.any’ file:
AnyKinEqSimpleDriver CervicalFlexionRhythmDrv = {
AnyKinMeasureLinComb Measure = {
AnyKinMeasure &u0 = ..SkullThoraxFlexion;
AnyKinMeasure &u1 = ...C1C0Jnt;
AnyKinMeasure &u2 = ..C3C2JntFlexion;
AnyKinMeasure &u3 = ..C4C3JntFlexion;
AnyKinMeasure &u4 = ..C5C4JntFlexion;
AnyKinMeasure &u5 = ..C6C5JntFlexion;
AnyKinMeasure &u6 = ..C7C6JntFlexion;
AnyKinMeasure &u7 = ..T1C7JntFlexion;
OutDim = 6;
Const = {0, 0, 0, 0, 0, 0};
Coef = {
{40/122, 1, 0, 0, 0, 0, 0, 0},
{0, 0, 1, -1, 0, 0, 0, 0},
{0, 0, 0, 1, -1, 0, 0, 0},
{0, 0, 0, 0, 1, -1, 0, 0},
{0, 0, 0, 0, 0, 1, -1, 0},
{0, 0, 0, 0, 0, 0, 1, -1}};
}; // Measure
DriverPos = {0, 0, 0, 0, 0, 0};
DriverVel = {0, 0, 0, 0, 0, 0};
Reaction.Type = {Off,Off,Off, Off,Off,Off};
}; // CervicalFlexionRhythmDrv
AnyKinEqSimpleDriver CervicalLateralBendingRhythmDrv = {
AnyKinMeasureLinComb Measure = {
AnyKinMeasure &u2 = ..C3C2JntLateralBending;
AnyKinMeasure &u3 = ..C4C3JntLateralBending;
AnyKinMeasure &u4 = ..C5C4JntLateralBending;
AnyKinMeasure &u5 = ..C6C5JntLateralBending;
AnyKinMeasure &u6 = ..C7C6JntLateralBending;
AnyKinMeasure &u7 = ..T1C7JntLateralBending;
OutDim = 5;
Const = {0, 0, 0, 0, 0};
Coef = {
{1, -1, 0, 0, 0, 0},
{0, 1, -1, 0, 0, 0},
{0, 0, 1, -1, 0, 0},
{0, 0, 0, 1, -1, 0},
{0, 0, 0, 0, 1, -1}};
}; // Measure
DriverPos = {0, 0, 0, 0, 0};
DriverVel = {0, 0, 0, 0, 0};
Reaction.Type = {Off,Off,Off, Off,Off};
}; // CervicalLateralBendingRhythmDrv
AnyKinEqSimpleDriver CervicalRotationRhythmDrv = {
AnyKinMeasureLinComb Measure = {
AnyKinMeasure &u0 = ..SkullThoraxRotation;
AnyKinMeasure &u1 = ...C2C1Jnt;
AnyKinMeasure &u2 = ..C3C2JntRotation;
AnyKinMeasure &u3 = ..C4C3JntRotation;
AnyKinMeasure &u4 = ..C5C4JntRotation;
AnyKinMeasure &u5 = ..C6C5JntRotation;
AnyKinMeasure &u6 = ..C7C6JntRotation;
AnyKinMeasure &u7 = ..T1C7JntRotation;
OutDim = 6;
Const = {0, 0, 0, 0, 0, 0};
Coef = {
{77/132, 1, 0, 0, 0, 0, 0, 0},
{0, 0, 1, -1, 0, 0, 0, 0},
{0, 0, 0, 1, -1, 0, 0, 0},
{0, 0, 0, 0, 1, -1, 0, 0},
{0, 0, 0, 0, 0, 1, -1, 0},
{0, 0, 0, 0, 0, 0, 1, -1}};
}; // Measure
DriverPos = {0, 0, 0, 0, 0, 0};
DriverVel = {0, 0, 0, 0, 0, 0};
Reaction.Type = {Off,Off,Off, Off,Off,Off};
}; // CervicalRotationRhythmDrv
If you can change the ‘Coef’ values in the AnyKinMeasureLinComb objects, you can implement a different set of joint angle distribution.
- This question seems to be already answered in the other post:
http://forum.anyscript.org/showthread.php?p=20042#post20042
Best regards,
Moonki